//@version=5
indicator(title="Relative Strength Index", shorttitle="RSI", format=format.price, precision=2, timeframe="", timeframe_gaps=true)

// 定义移动平均函数，支持多种类型的移动平均
ma(source, length, type) =>
    switch type
        "SMA" => ta.sma(source, length)
        "Bollinger Bands" => ta.sma(source, length)
        "EMA" => ta.ema(source, length)
        "SMMA (RMA)" => ta.rma(source, length)
        "WMA" => ta.wma(source, length)
        "VWMA" => ta.vwma(source, length)


// 输入参数设置
rsiLengthInput = input.int(14, minval=1, title="RSI Length", group="RSI Settings")  // RSI周期长度
rsiSourceInput = input.source(close, "Source", group="RSI Settings")  // RSI计算的数据源
maTypeInput = input.string("SMA", title="MA Type", options=["SMA", "Bollinger Bands", "EMA", "SMMA (RMA)", "WMA", "VWMA"], group="MA Settings", display = display.data_window)  // 移动平均类型
maLengthInput = input.int(14, title="MA Length", group="MA Settings", display = display.data_window)  // 移动平均周期长度
bbMultInput = input.float(2.0, minval=0.001, maxval=50, title="BB StdDev", group="MA Settings", display = display.data_window)  // 布林带标准差倍数
showDivergence = input.bool(true, title="Show Divergence", group="RSI Settings", display = display.data_window)  // 是否显示背离信号

// 计算RSI
up = ta.rma(math.max(ta.change(rsiSourceInput), 0), rsiLengthInput)
down = ta.rma(-math.min(ta.change(rsiSourceInput), 0), rsiLengthInput)
rsi = down == 0 ? 100 : up == 0 ? 0 : 100 - (100 / (1 + up / down))
rsiMA = ma(rsi, maLengthInput, maTypeInput)
isBB = maTypeInput == "Bollinger Bands"

// 绘制RSI
rsiPlot = plot(rsi, "RSI", color=color.purple)
// 绘制 RSI的 移动平均线
// plot(rsiMA, "RSI-based MA", color=color.red) 
rsiUpperBand = hline(70, "RSI Upper Band", color=#787B86)  // RSI超买区域上限
midline = hline(50, "RSI Middle Band", color=color.new(#787B86, 50))  // RSI中线
rsiLowerBand = hline(30, "RSI Lower Band", color=#787B86)  // RSI超卖区域下限
fill(rsiUpperBand, rsiLowerBand, color=color.rgb(126, 87, 194, 90), title="RSI Background Fill")  // 填充RSI背景

// 如果选择布林带作为移动平均类型，绘制布林带上下轨
bbUpperBand = plot(isBB ? rsiMA + ta.stdev(rsi, maLengthInput) * bbMultInput : na, title = "Upper Bollinger Band", color=color.green)
bbLowerBand = plot(isBB ? rsiMA - ta.stdev(rsi, maLengthInput) * bbMultInput : na, title = "Lower Bollinger Band", color=color.green)
fill(bbUpperBand, bbLowerBand, color= isBB ? color.new(color.green, 90) : na, title="Bollinger Bands Background Fill")  // 填充布林带背景

// 设置超买和超卖区域的渐变填充颜色
midLinePlot = plot(50, color = na, editable = false, display = display.none)
fill(rsiPlot, midLinePlot, 100, 70, top_color = color.new(color.green, 0), bottom_color = color.new(color.green, 100),  title = "Overbought Gradient Fill")
fill(rsiPlot, midLinePlot, 30,  0,  top_color = color.new(color.red, 100), bottom_color = color.new(color.red, 0),      title = "Oversold Gradient Fill")

// 背离设置
lookbackRight = 5
lookbackLeft = 5
rangeUpper = 60
rangeLower = 5
bearColor = color.red
bullColor = color.green
textColor = color.white
noneColor = color.new(color.white, 100)

// 检查是否有Pivot High/Low
plFound = na(ta.pivotlow(rsi, lookbackLeft, lookbackRight)) ? false : true
phFound = na(ta.pivothigh(rsi, lookbackLeft, lookbackRight)) ? false : true

// 判断是否在范围内
_inRange(cond) =>
	bars = ta.barssince(cond == true)
	rangeLower <= bars and bars <= rangeUpper

//------------------------------------------------------------------------------
// 常规看涨背离
// RSI：更高的低点
rsiHL = rsi[lookbackRight] > ta.valuewhen(plFound, rsi[lookbackRight], 1) and _inRange(plFound[1])

// 价格：更低的低点
priceLL = low[lookbackRight] < ta.valuewhen(plFound, low[lookbackRight], 1)
bullCondAlert = priceLL and rsiHL and plFound
bullCond = showDivergence and bullCondAlert

plot(
     plFound ? rsi[lookbackRight] : na,
     offset=-lookbackRight,
     title="Regular Bullish",
     linewidth=2,
     color=(bullCond ? bullColor : noneColor),
	 display = display.pane
     )
// 图中标识出看涨背离
plotshape(
	 bullCond ? rsi[lookbackRight] : na,
	 offset=-lookbackRight,
	 title="Regular Bullish Label",
	 text=" Bull ",
	 style=shape.labelup,
	 location=location.absolute,
	 color=bullColor,
	 textcolor=textColor
	 )

//------------------------------------------------------------------------------
// 常规看跌背离
// RSI：更低的高点
rsiLH = rsi[lookbackRight] < ta.valuewhen(phFound, rsi[lookbackRight], 1) and _inRange(phFound[1])

// 价格：更高的高点
priceHH = high[lookbackRight] > ta.valuewhen(phFound, high[lookbackRight], 1)

bearCondAlert = priceHH and rsiLH and phFound
bearCond = showDivergence and bearCondAlert

plot(
	 phFound ? rsi[lookbackRight] : na,
	 offset=-lookbackRight,
	 title="Regular Bearish",
	 linewidth=2,
	 color=(bearCond ? bearColor : noneColor),
	 display = display.pane
	 )

// 图中标识出看跌背离
plotshape(
	 bearCond ? rsi[lookbackRight] : na,
	 offset=-lookbackRight,
	 title="Regular Bearish Label",
	 text=" Bear ",
	 style=shape.labeldown,
	 location=location.absolute,
	 color=bearColor,
	 textcolor=textColor
	 )

alertcondition(bullCondAlert, title='Regular Bullish Divergence', message="发现一个新的常规看涨背离。")
alertcondition(bearCondAlert, title='Regular Bearish Divergence', message='发现一个新的常规看跌背离。')



// 根据RSI值设置背景颜色
// bgcolor(rsi > 50 ? color.new(color.green, 75) : color.new(color.red, 75))
// bgcolor(rsi > 70 ? color.new(color.red, 75) : rsi < 20 ? color.new(color.green, 75) : na)
// 超买和看跌背离 ； 超卖和看展背离
bgcolor((rsi > 70 or bearCondAlert )? color.new(color.red, 75) : (rsi < 20 or bullCondAlert )? color.new(color.green, 75) : na)
// 背离
// bgcolor(bearCondAlert? color.new(color.red, 75) : bullCondAlert? color.new(color.green, 75) : na)